ซ้อนกันหากแบบสอบถามในบริบทของแพตช์ NetLogo

วิธีที่คุณเข้าใกล้มัน คุณต้องมีข้อความที่ค่อนข้างซับซ้อน เช่น:

let upper-blues patches with [color = blue and
   any? other patches with [color = blue and pxcor = [pxcor] of myself
        and pycor < [pycor] of myself and pycor > [pycor] of myself - 25]

ฉันเชื่อว่านี่จะง่ายกว่ามากในการมองมุมมองของแพตช์ที่คุณต้องการให้กลายเป็นสีเขียว หากฉันตีความเงื่อนไขของคุณอย่างถูกต้อง แพตช์นั้นจะต้องหาแพตช์สีเหลืองที่ใกล้ที่สุดด้านบน/ล่าง/ที่ จากนั้นตรวจสอบว่ามีแพตช์สีน้ำเงินสองแพตช์ที่คร่อมทั้งสีเหลืองและตัวมันเอง โดยมีแพตช์สีน้ำเงินอยู่ใกล้กันเพียงพอหรือไม่ ฉันถือว่าคุณปิดการห่อแล้ว

นี่คือแบบจำลองที่สมบูรณ์ที่ใส่เต่าสีแดงแทนที่จะเปลี่ยนแผ่นสีเขียว เพื่อให้คุณสามารถดูได้ว่าระบุแผ่นปะที่ถูกต้องหรือไม่

to setup
  clear-all
  ask patches [set pcolor white]
  ask n-of 100 patches [set pcolor blue]
  ask n-of 100 patches [set pcolor yellow]
end

to convert-to-green
  let turn-green nobody
  ask patches
  [ let my-column patches with [pxcor = [pxcor] of myself]
    let above-yellow min-one-of my-column with [pcolor = yellow and pycor >= [pycor] of myself][pycor]
    let above-blue ifelse-value (above-yellow != nobody) [min-one-of my-column with [pcolor = blue and pycor > [pycor] of above-yellow][pycor]][nobody]
    let below-yellow max-one-of my-column with [pcolor = yellow and pycor <= [pycor] of myself][pycor]
    let below-blue ifelse-value (below-yellow != nobody) [max-one-of my-column with [pcolor = blue and pycor < [pycor] of below-yellow][pycor]][nobody]
    if above-blue != nobody and below-blue != nobody and ([pycor] of above-blue - [pycor] of below-blue < 25)
    [ set turn-green (patch-set self turn-green)
    ]
  ]
  ask turn-green [sprout 1 [set color red]]
end

เมื่อคุณพอใจแล้ว การทำงานถูกต้องแล้ว ให้เปลี่ยน ask turn-green [sprout 1 [set color red]] เป็น ask turn-green [set pcolor green]

โค้ดนี้จะตรวจสอบแต่ละแพตช์ตามลำดับแบบสุ่ม และเพิ่มลงในชุดแพตช์ (เรียกว่าเทิร์นกรีน) หากตรงตามเงื่อนไข เมื่อทดสอบแพตช์ทั้งหมดแล้ว ชุดของแพตช์ที่เลือกจะเปลี่ยนสี วิธีนี้จะหลีกเลี่ยงปัญหาแพทช์สีเหลืองหรือสีน้ำเงินที่เปลี่ยนเป็นสีเขียวและไม่สามารถให้ตรวจสอบกับแพทช์ถัดไปได้