ค้นหาคำสองคำภายในไฟล์ .txt โดยใช้แบตช์ไฟล์

คำตอบของสเตฟานใช้งานได้ แต่จะพิมพ์ทุกคำที่ซ้ำกันหลาย ๆ ครั้งตามที่ปรากฏ นอกจากนี้ยังค่อนข้างไม่มีประสิทธิภาพ โดยอ่านไฟล์ทั้งหมดหนึ่งครั้งสำหรับทุกบรรทัดในไฟล์

นี่เป็นโซลูชันแบบแบตช์ที่ค่อนข้างง่ายที่จะพิมพ์คำที่ซ้ำกันแต่ละคำเพียงครั้งเดียว งานจะง่ายกว่ามากหากคุณใช้ SORT เพื่อจัดกลุ่มการจำลองทั้งหมดไว้ด้วยกัน อย่างไรก็ตาม คำสั่ง Windows SORT จะละเว้นตัวพิมพ์ ดังนั้น IF จะต้องละเว้นตัวพิมพ์ด้วย โซลูชันนี้จะอ่านไฟล์เพียงสองครั้งเท่านั้น โดยไม่คำนึงถึงขนาด หนึ่งครั้งสำหรับ SORT และหนึ่งครั้งสำหรับ FOR /F

@echo off
setlocal enableDelayedExpansion

set "prev="
set "dup="
for /f "delims=" %%W in ('sort test.txt') do (
  if /i %%W==!prev! (
    if not defined dup echo(%%W
    set dup=1
  ) else set "dup="
  set "prev=%%W"
)

หากคุณต้องการให้การเปรียบเทียบคำคำนึงถึงตัวพิมพ์เล็กและตัวพิมพ์ใหญ่ อัลกอริธึมด้านบนต้องใช้รูทีน SORT ที่คำนึงถึงตัวพิมพ์เล็กและตัวพิมพ์ใหญ่ ฉันได้เขียน JSORT.BAT เพื่อทำสิ่งนั้น (ในหมู่ สิ่งอื่น ๆ). เป็นสคริปต์ล้วนๆ (JScript แบบไฮบริด/แบทช์) ที่ทำงานบน Windows

แต่ถ้าคุณยินดีที่จะใช้ JScrpt/batch ไฮบริด การแก้ปัญหาจะง่ายมากหากคุณเพิ่ม JREPL.BAT นิพจน์ทั่วไปค้นหา/แทนที่ยูทิลิตี ตัวเลือก /M ช่วยให้ฉันค้นหาคำที่ซ้ำกันในการขึ้นบรรทัดใหม่ได้

jsort test.txt | jrepl "^(.+)$(\r?\n\1$)+" $1 /jmatch /m

มีเวลาเริ่มต้นที่สำคัญในการเริ่มการทำงานของเอ็นจิ้น JScript ดังนั้นโซลูชันนี้จึงช้ากว่าโซลูชันแบบแบตช์จริงเล็กน้อยหากไฟล์มีขนาดเล็ก แต่หากไฟล์มีขนาดใหญ่ ก็จะเร็วกว่าโซลูชันแบบแบตช์เพียงอย่างเดียว

นี่คือสิ่งที่จะเริ่มต้นด้วย:

@echo off
for /f %%i in (t.txt) do for /f %%a in ('type t.txt^|findstr /x "%%i"^|find /v /c "" ') do if %%a gtr 1 echo %%i

findstrนับไม่ได้ เลยต้องใช้ find /c เป็นตัวช่วย

ดู find /?, findstr /? และ for /? สำหรับข้อมูลเพิ่มเติม