การอัปเดต/การจัดการข้อมูล SAS

ดูเหมือนว่าโค้ดต่อไปนี้จะใช้ได้กับข้อมูลของคุณเหมือนเดิม มันใช้ประโยชน์จากวัตถุแฮชโดยที่ 'Original_Record' ยังคงอยู่และ 'นับ' จะถูกบวกเข้าด้วยกัน องค์ประกอบบางอย่างอาจซ้ำซ้อนในตอนนี้ (อาจไม่จำเป็นต้องใช้ '_start')

data have;
    infile cards truncover;
    input (ID      Record_ID   Correction_ID) (:$8.);
    cards;
0001    A001    
0002    A002    
0003    A003        A001
0004    A004        A002
0005    A005    
0006    A006        A004
0007    A007        
0008    A008        A006
0009    A009        A003
;;;;
run;

data want;
    if _n_=1 then
        do;
            declare hash h();
            h.definekey('_end');
            h.definedata('_end', '_start', '_origin', 'count');
            h.definedone();
            length _end _start _origin $ 8;
            /*call missing (of _:, count);*/
        end;

    set have;

    if missing (correction_id) then
        do;
            original_record=record_id;
            count=0;
        end;
    else
        do;
            rc=h.find(key:correction_id);

            if rc ne 0 then
                    do;
/*if there is no match, this would be the first time of modifying, '_origin' is set to the value of correction_id, count is set to 1*/
                    _origin=correction_id;
                    count=1;
                end;
            else
                do;

/*if there is a match, then '_origin stays the same, so no  
operation is needed, but count increased by 1*/
                    count=count+1;
                end;

            _end=record_id;
            _start=correction_id;
            Original_Record=_origin;
            rc=h.replace();
        end;

    drop rc _:;
run;

หากคุณมีใบอนุญาต SAS/OR โค้ดนี้ก็จะทำงานเหมือนกันโดยประมาณ แต่ง่ายกว่านั้น เนื่องจากอาร์เรย์ PROC OPTMODEL เป็นแฮช มันโหลดข้อมูลทั้งหมดลงใน RAM ดังนั้นราคาของความเรียบง่ายคือการใช้หน่วยความจำ

ฉันจะใช้ชุดข้อมูลของ Haikuo ซ้ำ:

 data have;
    infile cards truncover;
    input (ID      Record_ID   Correction_ID) (:$8.);
    cards;
    0001    A001    
    0002    A002    
    0003    A003        A001
    0004    A004        A002
    0005    A005    
    0006    A006        A004
    0007    A007        
    0008    A008        A006
    0009    A009        A003
;

ฉันไม่คิดว่าเราต้องการ ID จริงๆ ดังนั้นฉันจึงเพิกเฉยเพื่อทำให้โค้ดมีความชัดเจนมากขึ้น ไม่ได้ใช้ภายใน แต่คุณสามารถเพิ่มลงในคำสั่ง read data และ create data ได้หากต้องการ

proc optmodel;
    set<str,str> RECORDS;
    set ALL = setof{<i,j> in RECORDS} i;
    str parent  {ALL diff {<i,('')> in RECORDS}};
    str original{i in ALL} init i;
    num count   {     ALL} init 0;

    read data have into RECORDS=[Record_Id Correction_ID];
    for {<ri,rj> in RECORDS: rj ~= ''} do;
        parent  [ri] = rj;
        count   [ri] = count   [parent[ri]] + 1;
        original[ri] = original[parent[ri]];
    end;
    create data want from [Record_ID Correction_ID]=RECORDS 
        Original_Record = original[Record_ID] Count = count[Record_ID];
quit;