การเขียนโค้ด vba ใน sas

วิธีทั่วไปในการทำเช่นนี้คือการใช้ไฟล์เทมเพลต คุณได้บันทึกเทมเพลตของคุณแล้ว ซึ่งมีแมโคร Excel บันทึกอยู่ในนั้น (และอาจมีการจัดรูปแบบบางส่วนด้วย การใช้ DDE คุณไม่จำเป็นต้องเริ่มต้นด้วยแผ่นงานเปล่าเลย)

คุณสามารถใช้ DDE เพื่อเติมข้อมูลในสมุดงาน/แผ่นงานเทมเพลต จากนั้น "บันทึกเป็น" ไฟล์อื่น หรือคุณสามารถใช้ DDE เพื่อสร้างสมุดงานและแผ่นงานใหม่ เปิดสมุดงานเทมเพลต เรียกใช้แมโคร ปิดเทมเพลต ซึ่งคุณทำอาจขึ้นอยู่กับว่าคุณต้องการกระจายมาโครพร้อมกับผลลัพธ์ของคุณหรือไม่

วิธีนี้ช่วยให้คุณสามารถเรียกใช้ทุกสิ่งโดยไม่ต้องโต้ตอบกับมัน แต่อย่างใด - คุณไม่จำเป็นต้องเพิ่มมาโครใหม่หรืออะไรก็ตาม เนื่องจากมีแมโครเทมเพลตอยู่แล้ว ทุกอย่างสามารถทำได้ในการดำเนินการเดียวด้วยวิธีนี้

ซึ่งแสดงไว้เป็นตัวอย่างในรายงาน ทีละขั้นตอนในการใช้ SAS® DDE เพื่อ สร้างกราฟ Excel ตามการสังเกตการณ์ N จากชุดข้อมูล SAS รวมถึงเอกสารอื่นๆ อีกหลายเรื่องเกี่ยวกับหัวข้อนี้

ฉันมักจะพบว่า DDE ค่อนข้างเทอะทะและจะรู้สึกแย่หากคุณแตะสมุดงาน Excel ในขณะที่กำลังทำงานอยู่ ตัวอย่างนี้เขียน VBscript ไปยังพื้นที่ทำงาน sas จากนั้นจึงดำเนินการ iut โดยพื้นฐานแล้ว คุณสามารถรับคำสั่ง put เพื่อเขียนโค้ดสำหรับสิ่งที่คุณต้องการให้โปรแกรมทำ และสามารถขับเคลื่อนโดยสิ่งที่อยู่ในชุดข้อมูล SAS ตัวอย่างนี้เพิ่มส่วนหัวและส่วนท้ายให้กับสเปรดชีต Excel ที่มีอยู่...

%macro xlHeadFoot(WorkBookPath=,Header=FileName,Footer=SheetName,onlySheet=);

  %local _shortpath WorkBook;

  data _null_;
    length header footer $200;
    header=ifc(lowcase("&header.")='filename' or lowcase("&header.")='sheetname',tranwrd(tranwrd(lowcase("&header."),'filename','&F'),'sheetname','&A'),"&header.");
    footer=ifc(lowcase("&footer.")='filename' or lowcase("&footer.")='sheetname',tranwrd(tranwrd(lowcase("&footer."),'filename','&F'),'sheetname','&A'),"&footer.");
    call symput("header",trim(header));
    call symput("footer",trim(footer));
  run;

  %let WorkBook=%scan(&WorkBookPath.,%sysfunc(countw(&WorkBookPath.,\)),\);

    %* ***********************************************;
    %* get the short DOS name for the workspace folder;

    data _null_;
      rc=filename("inpipe",catx('"','for %I in (',"%sysfunc(pathname(work))",') do echo %~sI'),"pipe");
    run;

    data _null_;
      infile inpipe truncover end=last;
      input @1 data $256. ;
      rc=filename("inpipe","");
      if last then call symput('_shortpath',trim(data));
    run;

    %* *******************************;
    %* tidy up any previous executions;

    data _null_;
      if fileexist("&_shortpath\testx.vbs") then do;
        rc=filename("dump","&_shortpath\testx.vbs");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
      end;
      if fileexist("&_shortpath\xmlFile.xml") then do;
        rc=filename("dump","");
        rc=filename("dump","&_shortpath\xmlFile.xml");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
        rc=filename("dump","");
      end;
    run;


  %if %sysfunc(fileexist("&WorkBookPath."))=1 %then %do;


    data null;
      file "%sysfunc(pathname(work))\testx.vbs";
      put @1 'Set objExcel = CreateObject("Excel.Application")';
      put @1 'objExcel.Application.Visible = True';
      put @1 'objExcel.Workbooks.open  "' "&WorkBookPath." '"' ;
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'onlySheetExisits=False';
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then onlySheetExisits=True';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next';
      %end;
      %else %do;
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next'; 
      %end;

      put @1 'objExcel.Workbooks("' "&WorkBook." '").save';
      put @1 'objExcel.Workbooks("' "&WorkBook." '").Close';
      put @1 'objExcel.Application.Quit';
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'if onlySheetExisits=False then msgbox "Error! Could not find Worksheet: '"&onlySheet."' in Workbook: "' ' & vbcr & ' '" '"&WorkBookPath." '",16,"SAS: '"&SYSMACRONAME"'"';
      %end;

    run;


    x %sysfunc(quote("&_shortpath.\testx.vbs")); 

  %end;
  %else %put %str(ERR)OR: [&SYSMACRONAME.] Unable to open: &WorkBookPath.  - check it exists!;


%mend;

ด้วย DDE คุณสามารถตั้งค่าตัวกรองใน SAS:

data _null_;
    FILE CMDS;
    /* select your worksheet */
    put '[workbook.select("your_sheet")]';
    /* select the column range you want to set the filter */
    put '[select("r1c2:r1c5")]';
    /* set filter */
    put '[filter]';
run;