การสำรวจ/แก้ไขโครงสร้างข้อมูล Groovy

เมื่อดูที่ inventory จริงๆ แล้วมันสามารถแสดงได้ด้วยสิ่งที่ต้องการ

@Immutable(copyWith = true)
class Car {
    String make
    String model
    int year
    String color
    boolean awd

    List<String> features
    List<String> bugs
}

เมื่อคุณพอใจกับการเขียนรายการใหม่แล้ว (และโดยทั่วไปมีเหตุผลบางประการที่จะไม่ทำเช่นนั้น) คุณสามารถเพิ่มคำอธิบายประกอบ @Immutable ได้ เนื่องจากเป็น "ผลข้างเคียง" คุณสามารถเพิ่ม copyWith = true เพื่อรับวิธีการคัดลอกได้

คำจำกัดความของ inventory อาจมีลักษณะดังนี้:

    def inventory = [
        new Car(
            make: "Subaru",
            model: "Impreza WRX",
            year: 2010,
            color: "Blue",
            features: ["Premium sound", "Brembo brakes"],
            bugs: ["Leaks oil", "Needs new transmission"]),
        new Car(
            make: "Jeep",
            model: "Wrangler",
            year: 13,
            awd: true,
            features: ["Soft top"],
            bugs: ["Doesn't start", "Flooded"])
        ]

ซึ่งให้การแสดงข้อมูลของคุณอย่างไม่เปลี่ยนแปลง จากนั้น คุณสามารถสำรวจและเปลี่ยนแปลงข้อมูลของคุณโดยใช้ API การรวบรวม ในกรณีของคุณ:

    def result = inventory
        .collect { it.copyWith(bugs: []) }
        .collect { it.copyWith(year: 
                     it.year < 2000 ? it.year + 2000 : it.year) }
        .collect {
            if (it.awd) { 
                it.copyWith(features: it.features + "AWD")
            } else {
                it
            } 

การเปลี่ยนแปลงแต่ละครั้งจะถูกนำไปใช้แยกกัน (และมีเพียงอินสแตนซ์ที่ไม่เปลี่ยนรูปแบบเท่านั้นที่ไหลผ่านไปป์ไลน์นั้น)

หากคุณต้องการลบรายการข้อบกพร่องที่ว่างเปล่าและ/หรือคุณสมบัติ awd ให้กำหนดคลาสเป้าหมาย:

class FixedCar {
    String make
    String model
    int year
    String color

    List<String> features

    static FixedCar apply(Car car) {
        new FixedCar(
            make: car.make,
            model: car.model,
            year: car.year,
            color: car.color,
            features: car.features)
    }
}

และเพิ่มการโทรอีกครั้งไปที่ collect:

    def result = inventory
        .collect { it.copyWith(bugs: []) }
        .collect { it.copyWith(year: 
                     it.year < 2000 ? it.year + 2000 : it.year) }
        .collect {
            if (it.awd) { 
                it.copyWith(features: it.features + "AWD")
            } else {
                it
            } 
        }.collect { FixedCar.apply(it) }