เหตุใดการเพิ่ม MouseArea ด้วย anchors.fill: parent ทำให้แถวซ้อนกัน

อาจเป็นไปได้ว่าข้อผิดพลาดในการยึดทำให้เกิดสถานะที่ไม่สอดคล้องกัน โดยที่ Row จะไม่สืบทอดความสูงจากข้อความที่ล้อมรอบ เช่นเดียวกับที่ทำโดยไม่มีการยึดรายการ ซึ่งส่งผลให้มีความสูงเป็นศูนย์และการเรียงซ้อน

ในกรณีนี้ คุณสามารถรวม Row ไว้ใน Item และใช้การเติม MouseArea ที่ส่วนหลังได้ โค้ดผลลัพธ์ โดยตั้งค่าความสูงและความกว้างของผู้รับมอบสิทธิ์อย่างถูกต้อง จะมีลักษณะคล้ายกับโค้ดต่อไปนี้ (โปรดทราบ ฉันได้ลบบทบาทและโมเดลในโค้ดของคุณแล้วเนื่องจากส่วนหลังไม่มีอยู่ในโค้ดที่ให้มา ข้อมูลโค้ด):

import QtQuick 2.4
import QtQuick.Window 2.2
import QtQuick.Layouts 1.1
import QtQuick.Controls 1.2

ApplicationWindow {
    visible:  true
    width: 200
    height: 300
    
    ListView {
        id: myListView
        model: 20
        anchors.fill: parent
        
        delegate: Item {
            width: myListView.width
            height: text1.height            // set the height!
            Row {
                id: row
                anchors.fill: parent
                spacing: 5
                
                Text {
                    id: text1
                    text: "id"
                    width: 25
                    horizontalAlignment: Text.AlignHCenter
                }
                
                Text {
                    text: "description"
                }
                
            }
            MouseArea {                     // fills the delegate Item, not the Row!
                anchors.fill: parent
                onClicked: {
                    myListView.currentIndex = index
                    console.info("Area clicked! Index: " + index)
                }
            }
        }
    }
}