การเชื่อมบรรทัดจากไฟล์ข้อความ - Excel VBA

ดังนั้นฉันจะทำให้มันแตกต่างออกไปเล็กน้อย ใช้วิธีการที่ทันสมัยมากขึ้นในการอ่านไฟล์

ดูรายละเอียดเพิ่มเติมเกี่ยวกับวิธีการอ่านไฟล์ *.txt ใน VBA - here

หมายเหตุ: คุณต้องเพิ่มการอ้างอิงถึง Microsoft Scripting Runtime ผ่าน VBE -> เครื่องมือ -> การอ้างอิง

Option Explicit

Sub ReadTxtFile()

    Dim oFSO As New FileSystemObject
    Dim oFS As TextStream

    Dim filePath As String
    filePath = "C:\Users\" & Environ$("username") & "\Desktop\foo.txt"

    If Not fileExist(filePath) Then GoTo FileDoesntExist

    On Error GoTo Err

    ReDim arr(0) As String
    Dim s As String

    Set oFS = oFSO.OpenTextFile(filePath)
    Do While Not oFS.AtEndOfStream
        Dim line As String
        line = oFS.ReadLine
        If InStr(line, "-- Begin") = 0 And InStr(line, "^") = 0 Then
            s = s & line
        End If
        If InStr(line, "^") > 0 Then
            arr(UBound(arr)) = s
            ReDim Preserve arr(UBound(arr) + 1)
            s = vbNullString
        End If
    Loop
    ReDim Preserve arr(UBound(arr) - 1)
    oFS.Close

    Dim k As Long
    For k = LBound(arr) To UBound(arr)
        Debug.Print k, arr(k)
    Next k
    Exit Sub

FileDoesntExist:
    MsgBox "File Doesn't Exist", vbCritical, "File not found!"
    Exit Sub

Err:
    MsgBox "Error while reading the file.", vbCritical, vbNullString
    oFS.Close
    Exit Sub

End Sub


Function fileExist(path As String) As Boolean
    fileExist = IIf(Dir(path) <> vbNullString, True, False)
End Function

foo.txt มีลักษณะเช่นนี้

-- Begin 
  Line1
  Line2
  Line3
      ^
-- Begin
  Line1
  Line2
  Line3
  Line4
      ^

อาร์เรย์ของคุณมีลักษณะเช่นนี้