ฉันจะลบลิงก์ภายนอกออกจาก HTML โดยใช้ Perl ได้อย่างไร

สะท้อนความคิดเห็นของ Chris Lutz ฉันหวังว่าสิ่งต่อไปนี้จะแสดงให้เห็นว่าการใช้ parser นั้นตรงไปตรงมามาก (โดยเฉพาะถ้าคุณต้องการจัดการกับอินพุตที่คุณยังไม่เคยเห็นเช่น <a class="external" href="/th...">) แทนที่จะรวบรวมวิธีแก้ปัญหาที่เปราะบางโดยใช้ s///

หากคุณกำลังจะใช้เส้นทาง s/// อย่างน้อยก็บอกตรงๆ เลย ขึ้นอยู่กับแอตทริบิวต์ href ที่เป็นตัวพิมพ์ใหญ่ทั้งหมด แทนที่จะสร้างภาพลวงตาของความยืดหยุ่น

แก้ไข: ตามความต้องการยอดนิยม ;-) นี่คือเวอร์ชันที่ใช้ HTML::TokeParser::Simple. ดูประวัติการแก้ไขสำหรับเวอร์ชันโดยใช้เพียง HTML::TokeParser

#!/usr/bin/perl

use strict; use warnings;
use HTML::TokeParser::Simple;

my $parser = HTML::TokeParser::Simple->new(\*DATA);

while ( my $token = $parser->get_token ) {
    if ($token->is_start_tag('a')) {
        my $href = $token->get_attr('href');
        if (defined $href and $href !~ /^#/) {
            print $parser->get_trimmed_text('/a');
            $parser->get_token; # discard </a>
            next;
        }
    }
    print $token->as_is;
}

__DATA__
<a HREF="/th#FN1" name="01">1</a>
some other html
<a href="/th155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="/thtest.html">click here >>></a>
either</p>

เอาท์พุท:

C:\Temp> hjk
<a HREF="/th#FN1" name="01">1</a>
some other html
No. 155 <!-- end tag not necessarily on the same line -->
An example you might not have considered

<p>Maybe you did not consider click here >>>
either</p>

หมายเหตุ: โซลูชันที่ใช้ regex ที่คุณทำเครื่องหมายว่า "ถูกต้อง" จะหยุดทำงานหากไฟล์ที่เชื่อมโยงให้มีนามสกุล .html แทนที่จะเป็น .htm ด้วยเหตุนี้ เราพบว่าคุณกังวลเรื่องการไม่อาศัยแอตทริบิวต์ตัวพิมพ์ใหญ่ HREF ที่ไม่สมเหตุสมผล หากคุณต้องการความรวดเร็วและสกปรกจริงๆ คุณไม่ควรกังวลกับสิ่งอื่นใด และคุณควรใช้ตัวพิมพ์ใหญ่ทั้งหมด HREF และจัดการกับมันให้เสร็จ อย่างไรก็ตาม หากคุณต้องการให้แน่ใจว่าโค้ดของคุณทำงานกับเอกสารได้หลากหลายและใช้งานได้นานกว่ามาก คุณควรใช้ parser ที่เหมาะสม

ตัวแยกวิเคราะห์ประเภท SAX อีกเล็กน้อยคือ HTML::Parser:

use strict;
use warnings;

use English qw<$OS_ERROR>;
use HTML::Parser;
use List::Util qw<first>;

my $omitted;

sub tag_handler { 
    my ( $self, $tag_name, $text, $attr_hashref ) = @_;
    if ( $tag_name eq 'a' ) { 
        my $href = first {; defined } @$attr_hashref{ qw<href HREF> };
        $omitted = substr( $href, 0, 7 ) eq 'http://';
        return if $omitted;
    }
    print $text;
}

sub end_handler { 
    my $tag_name = shift;
    if ( $tag_name eq 'a' && $omitted ) { 
        $omitted = false;
        return;
    }
    print shift;
}

my $parser
    = HTML::Parser->new( api_version => 3
                       , default_h   => [ sub { print shift; }, 'text' ]
                       , start_h     => [ \&tag_handler, 'self,tagname,text,attr' ]
                       , end_h       => [ \&end_handler, 'tagname,text' ]
                       );
$parser->parse_file( $path_to_file ) or die $OS_ERROR;

อีกวิธีหนึ่ง ฉันชอบ HTML::TreeBuilder และ ตระกูล.

#!/usr/bin/perl
use strict;
use warnings;
use HTML::TreeBuilder;

my $root = HTML::TreeBuilder->new_from_file(\*DATA);
foreach my $a ($root->find_by_tag_name('a')) {
    if ($a->attr('href') !~ /^#/) {
        $a->replace_with_content($a->as_text);
    }
}
print $root->as_HTML(undef, "\t");

__DATA__
<a HREF="/th#FN1" name="01">1</a>
some other html
<a href="/th155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="/thtest.html">click here >>></a>
either</p>

ทำไมไม่เพียงแต่ลบลิงก์ที่แอตทริบิวต์ href ไม่ได้ขึ้นต้นด้วยเครื่องหมายปอนด์ออกเท่านั้น บางสิ่งเช่นนี้:

html =~ s/<a href="/th[^#][^"]*?">(.+?)<\/a>/$1/sig;

ง่ายกว่านั้นอีก หากคุณไม่สนใจแอตทริบิวต์ของแท็ก:

$html =~ s/<a[^>]+>(.+?)<\/a>/$1/sig;