Saya perlu menemukan kombinasi dalam daftar daftar. Misalnya, berikan daftar berikut,
List = [[1, 2], [1, 2, 3]]
Ini harus menjadi outputnya,
Comb = [[1,1],[1,2],[1,3],[2,1],[2,2],[2,3]]
Contoh lain:
List = [[1,2],[1,2],[1,2,3]]
Comb = [[1,1,1],[1,1,2],[1,1,3],[1,2,1],[1,2,2],[1,2,3]....etc]
Saya tahu cara melakukannya untuk daftar dengan dua subdaftar tetapi itu harus berfungsi untuk sejumlah subdaftar.
Saya baru mengenal Prolog, mohon bantuannya.
Jawaban ini memburu hadiah yang ditawarkan "untuk solusi murni yang juga memperhitungkan Ess". Di sini kami menggeneralisasi jawaban sebelumnya seperti ini:
list_crossproduct(Xs, []) :-
member([], Xs).
list_crossproduct(Xs, Ess) :-
Ess = [E0|_],
same_length(E0, Xs),
maplist(maybelonger_than(Ess), Xs),
list_comb(Xs, Ess).
maybelonger_than(Xs, Ys) :-
maybeshorter_than(Ys, Xs).
maybeshorter_than([], _).
maybeshorter_than([_|Xs], [_|Ys]) :-
maybeshorter_than(Xs, Ys).
list_crossproduct/2 menjadi dua arah dengan menghubungkan Xs dan Ess lebih awal.
?- list_comb(Xs, [[1,2,3],[1,2,4],[1,2,5]]). nontermination % BAD! ?- list_crossproduct(Xs, [[1,2,3],[1,2,4],[1,2,5]]). Xs = [[1],[2],[3,4,5]] % this now works, too ; false.
Contoh kueri yang memiliki banyak jawaban:
?- list_crossproduct(Xs, [[1,2,3],[1,2,4],[1,2,5],X,Y,Z]).
X = [1,2,_A],
Y = [1,2,_B],
Z = [1,2,_C], Xs = [[1],[2],[3,4,5,_A,_B,_C]]
; X = [1,_A,3],
Y = [1,_A,4],
Z = [1,_A,5], Xs = [[1],[2,_A],[3,4,5]]
; X = [_A,2,3],
Y = [_A,2,4],
Z = [_A,2,5], Xs = [[1,_A],[2],[3,4,5]]
; false.
nilmemberd(Xs) daripada member([],Xs).
- person repeat; 26.03.2020
Untuk kelengkapannya, berikut adalah versi augmented dari versi komentar saya. Catatan nilmemberd_t/2 yang terinspirasi oleh memberd_t/2.
nilmemberd_t([], false).
nilmemberd_t([X|Xs], T) :-
if_(nil_t(X), T = true, nilmemberd_t(Xs, T)).
nil_t([], true).
nil_t([_|_], false).
list_comb(List, []) :-
nilmemberd_t(List, true).
list_comb(List, Ess) :-
bagof(Es, maplist(member,Es,List), Ess).
Versi di atas menunjukkan bahwa "hanya" klausa pertama yang hilang dalam tanggapan komentar saya. Mungkin lebih pendek lagi dengan:
nilmemberd([[]|_]).
nilmemberd([[_|_]|Nils]) :-
nilmemberd(Nils).
Ini seharusnya berfungsi untuk Prolog tanpa kendala. Dengan adanya batasan, bagof/3 harus dipertimbangkan kembali karena batasan penyalinan adalah medan yang tidak jelas.
findall alih-alih bagof, untuk menghindari findall( Es, maplist( member,Es, [[1,2],t,[1]]), Ess). salah berhasil dengan [] alih-alih gagal. tetapi versi Anda juga gagal dengan [] untuk [[1,2],[],t,[1]].
- person Will Ness; 23.03.2020
bagof salah gagal pada [[1,1],[],[1]], namun findall benar (dalam hal ini) berhasil dengan [].
- person Will Ness; 23.03.2020
bagof/3 menangani variabel dengan benar sedangkan findall/3 menyalinnya dengan gila-gilaan
- person false; 23.03.2020
list_comb(T,[[1]]). itu adalah masalah yang jauh lebih kecil dibandingkan jika gagal, karena perulangan tidak dapat ditafsirkan sebagai benar atau salah. Dan untuk list_comb([[1,2],[],t,[1]],X).: Jika Anda melihat generalisasi ini sebagai masalah, mengapa Anda juga memilih sukses untuk list_comb([[1|non_list]],X)? Bagi saya ini tampaknya dapat diterima, Namun jika Anda bersikeras, harap masukkan maplist(maplist(\_^true), List) di akhir kedua aturan.
- person false; 24.03.2020
list_comb( [[1 | t]], X ). dengan kode saya dan gagal seperti yang diharapkan.
- person Will Ness; 26.03.2020
Berikut cara melakukannya menggunakan maplist/3 dan append/2:
list_comb([], [[]]). list_comb([Xs|Xss], Ess) :- Xs = [_|_], list_comb(Xss, Ess0), maplist(aux_x_comb(Ess0), Xs, Esss1), append(Esss1, Ess). aux_x_comb(Ess0, X, Ess1) :- maplist(head_tail_list(X), Ess0, Ess1). head_tail_list(X, Xs, [X|Xs]).
Contoh kueri:
?- list_comb([[a,b],[f,g],[x,y,z]], Ess).
Ess = [[a,f,x],[a,f,y],[a,f,z],
[a,g,x],[a,g,y],[a,g,z],
[b,f,x],[b,f,y],[b,f,z],
[b,g,x],[b,g,y],[b,g,z]].
Begini cara kerjanya! Sebagai contoh, pertimbangkan tujuan berikut:
list_comb([[a,b],[f,g],[x,y,z]], Ess)
list_comb([ [f,g],[x,y,z]], Ess0)
Bagaimana kita bisa berpindah dari Ess0 ke Ess?
Kami melihat jawaban atas pertanyaan terakhir:
?- list_comb([[f,g],[x,y,z]], Ess0). Ess0 = [[f,x],[f,y],[f,z], [g,x],[g,y],[g,z]].
... tempatkan a sebelum [f,x], ..., [g,z] ...
?- maplist(head_tail_list(a),
[[f,x],[f,y],[f,z],
[g,x],[g,y],[g,z]], X).
X = [[a,f,x],[a,f,y],[a,f,z],
[a,g,x],[a,g,y],[a,g,z]].... lalu lakukan hal yang sama untuk b.
maplist(aux_x_comb) membantu kami menangani semua item:
?- maplist(aux_x_comb([[f,x],[f,y],[f,z],
[g,x],[g,y],[g,z]]),
[a,b], X).
X = [[[a,f,x],[a,f,y],[a,f,z],
[a,g,x],[a,g,y],[a,g,z]],
[[b,f,x],[b,f,y],[b,f,z],
[b,g,x],[b,g,y],[b,g,z]]].Untuk berpindah dari daftar ke daftar, gunakan append/2.
Saya harap penjelasan ini lebih menjelaskan daripada membingungkan :)
Ess tidak berpengaruh terhadap penghentian - setidaknya dalam beberapa kasus
- person false; 17.03.2020
Perubahan dalam pendekatan @ false:
%list_comb( ++LL, -Ess)
list_comb( LL, Ess):-
is_list( LL),
maplist( is_list, LL),
findall( Es, maplist( member, Es, LL), Ess).
Pengujian:
41 ?- list_comb( [[1,2],[1],[1]], X). X = [[1, 1, 1], [2, 1, 1]]. 42 ?- list_comb( [[1,2],[1],[1,2,3]], X). X = [[1, 1, 1], [1, 1, 2], [1, 1, 3], [2, 1, 1], [2, 1, 2], [2, 1, 3]]. 43 ?- list_comb( [[1,2],[],[1,2,3]], X). X = []. 44 ?- list_comb( [[1,2],t,[1,2,3]], X). false. 45 ?- list_comb( t, X). false.
