Ekspor tag HANYA dari evernote?

Saya menemukan ini: Menggunakan Applescript untuk mengekspor daftar berdasarkan URL pada tag?, yang merupakan sumber yang bagus. Skrip asli (dari Veritrope) agak tua, tetapi berfungsi dengan baik untuk mengekspor judul catatan Evernote. Saya pikir akan relatif mudah untuk memodifikasi skrip ini untuk memasukkan HANYA tag di buku catatan saya ke dalam CSV. Tapi karena saya masih amatir dalam menulis naskah, dan belajar secara otodidak, saya tidak bisa membuatnya berhasil.

Adakah yang bisa mengarahkan saya ke arah yang benar? Tujuan utama saya adalah melakukan pemeliharaan tag, karena saya sekarang memiliki begitu banyak tag sehingga tidak lagi berguna. Jadi saya hanya ingin daftar tag - TIDAK harus dikaitkan dengan catatan. Satu kolom data.

Terima kasih, tumpukan.


applescript evernote
person SteveS    schedule 07.07.2015    source sumber
comment
dapatkah seseorang menjelaskan mengapa hal ini tidak dipilih? ini, dan pertanyaan terakhir saya, keduanya digeser tanpa penjelasan apa pun. komunitas ini nampaknya semakin tidak toleran; saya tidak mengerti. aku hanya mencoba belajar.   -  person SteveS    schedule 20.07.2015
comment
Pertanyaan Anda tidak disukai karena Anda tidak meminta jawaban spesifik untuk pertanyaan spesifik. Pertanyaan berbentuk Bagaimana cara melakukan X? atau Bisakah Anda mengarahkan saya ke arah yang benar? umumnya tidak berjalan dengan baik di StackOverflow. Anda diharapkan melakukan penelitian dan berusaha sebaik mungkin untuk menemukan solusi sendiri sebelum mengajukan pertanyaan di sini. stackoverflow.com/help/how-to-ask   -  person matthewayne    schedule 29.07.2015
comment
terima kasih. wah, komunitas ini sulit untuk diketahui!! Saya sebenarnya melakukan banyak penelitian mengenai hal ini, dan bahkan mencoba mengadaptasi skrip yang saya temukan sendiri. kurasa aku hanya tidak bertanya dengan cara yang benar. ungkapan, Lana. lagi pula, terima kasih juga untuk skrip di bawah ini. akan mencobanya sekarang.   -  person SteveS    schedule 30.07.2015

Jawaban (1)


arrow_upward
1
arrow_downward

Berikut adalah program AppleScript yang akan melakukan apa yang ingin Anda lakukan:

tell application "Evernote"
    set tagList to {}
    set allNotebooks to every notebook
    repeat with currentNotebook in allNotebooks
        set allNotes to every note in currentNotebook
        repeat with currentNote in allNotes
            set noteTags to (the tags of currentNote)
            repeat with currentTag in noteTags
                if tagList does not contain name of currentTag then
                    set the end of tagList to name of currentTag

                end if
            end repeat
        end repeat
    end repeat
end tell

set filePath to (path to desktop as text) & "Evernote Tags.csv"
set output to ""
repeat with currentTag in tagList
    set output to output & currentTag & ", "
end repeat

set theResult to writeTo(filePath, output, text, false)
if not theResult then display dialog "There was an error writing the data!"

on writeTo(targetFile, theData, dataType, apendData)
    -- targetFile is the path to the file you want to write
    -- theData is the data you want in the file.
    -- dataType is the data type of theData and it can be text, list, record etc.
    -- apendData is true to append theData to the end of the current contents of the file or false to overwrite it
    try
        set targetFile to targetFile as text
        set openFile to open for access file targetFile with write permission
        if apendData is false then set eof of openFile to 0
        write theData to openFile starting at eof as dataType
        close access openFile
        return true
    on error
        try
            close access file targetFile
        end try
        return false
    end try
end writeTo
person matthewayne    schedule 29.07.2015