Menulis kode vba di sas

Cara umum untuk melakukan ini adalah dengan menggunakan file templat. Anda telah menyimpan template Anda, yang memiliki makro excel yang disimpan di dalamnya (dan mungkin juga beberapa pemformatan telah dilakukan; menggunakan DDE Anda tidak harus memulai dengan lembar kerja kosong).

Anda bisa menggunakan DDE untuk mengisi buku kerja/lembar kerja templat, lalu "Simpan Sebagai" file lain, atau Anda bisa menggunakan DDE untuk membuat buku kerja dan lembar kerja baru, membuka buku kerja templat, menjalankan makro, dan menutup templat. Yang Anda lakukan mungkin bergantung pada apakah Anda ingin mendistribusikan makro beserta hasilnya.

Ini memungkinkan Anda menjalankan semuanya tanpa berinteraksi dengannya dengan cara apa pun - Anda tidak perlu menambahkan makro baru ke dalamnya atau apa pun, karena makro templat sudah ada. Semuanya bisa dilakukan dalam sekali jalan dengan cara ini.

Hal ini ditunjukkan misalnya dalam makalah Langkah-demi-Langkah dalam Menggunakan SAS® DDE untuk Membuat Grafik Excel Berdasarkan N Pengamatan dari Kumpulan Data SAS, serta beberapa makalah lain tentang subjek tersebut.

Saya selalu menganggap DDE agak kikuk dan membuat kesal jika Anda menyentuh buku kerja excel saat sedang berjalan. Contoh ini menulis skrip VB ke ruang kerja sas lalu mengeksekusi iut. Pada dasarnya Anda bisa mendapatkan pernyataan put untuk menulis kode untuk apa pun yang Anda ingin program lakukan dan itu dapat didorong oleh apa yang ada dalam kumpulan data SAS. Contoh ini menambahkan header dan foter ke spreadsheet excel yang ada...

%macro xlHeadFoot(WorkBookPath=,Header=FileName,Footer=SheetName,onlySheet=);

  %local _shortpath WorkBook;

  data _null_;
    length header footer $200;
    header=ifc(lowcase("&header.")='filename' or lowcase("&header.")='sheetname',tranwrd(tranwrd(lowcase("&header."),'filename','&F'),'sheetname','&A'),"&header.");
    footer=ifc(lowcase("&footer.")='filename' or lowcase("&footer.")='sheetname',tranwrd(tranwrd(lowcase("&footer."),'filename','&F'),'sheetname','&A'),"&footer.");
    call symput("header",trim(header));
    call symput("footer",trim(footer));
  run;

  %let WorkBook=%scan(&WorkBookPath.,%sysfunc(countw(&WorkBookPath.,\)),\);

    %* ***********************************************;
    %* get the short DOS name for the workspace folder;

    data _null_;
      rc=filename("inpipe",catx('"','for %I in (',"%sysfunc(pathname(work))",') do echo %~sI'),"pipe");
    run;

    data _null_;
      infile inpipe truncover end=last;
      input @1 data $256. ;
      rc=filename("inpipe","");
      if last then call symput('_shortpath',trim(data));
    run;

    %* *******************************;
    %* tidy up any previous executions;

    data _null_;
      if fileexist("&_shortpath\testx.vbs") then do;
        rc=filename("dump","&_shortpath\testx.vbs");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
      end;
      if fileexist("&_shortpath\xmlFile.xml") then do;
        rc=filename("dump","");
        rc=filename("dump","&_shortpath\xmlFile.xml");
        rc=fdelete('dump');
        msg=sysmsg();
        if msg ne '' then put msg=;
        rc=filename("dump","");
      end;
    run;


  %if %sysfunc(fileexist("&WorkBookPath."))=1 %then %do;


    data null;
      file "%sysfunc(pathname(work))\testx.vbs";
      put @1 'Set objExcel = CreateObject("Excel.Application")';
      put @1 'objExcel.Application.Visible = True';
      put @1 'objExcel.Workbooks.open  "' "&WorkBookPath." '"' ;
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'onlySheetExisits=False';
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then onlySheetExisits=True';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'if strcomp(sheet.name,"' "&onlySheet." '",1)=0 then sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next';
      %end;
      %else %do;
        put @1 'for each sheet in objExcel.Workbooks("' "&WorkBook." '").sheets';  
        put @1 'sheet.PageSetup.CenterHeader = "' "%str(&Header.)" '"';
        put @1 'sheet.PageSetup.CenterFooter = "' "%str(&Footer.)" '"';
        put @1 'Next'; 
      %end;

      put @1 'objExcel.Workbooks("' "&WorkBook." '").save';
      put @1 'objExcel.Workbooks("' "&WorkBook." '").Close';
      put @1 'objExcel.Application.Quit';
      %if %str(&onlySheet.) ne %str() %then %do;
        put @1 'if onlySheetExisits=False then msgbox "Error! Could not find Worksheet: '"&onlySheet."' in Workbook: "' ' & vbcr & ' '" '"&WorkBookPath." '",16,"SAS: '"&SYSMACRONAME"'"';
      %end;

    run;


    x %sysfunc(quote("&_shortpath.\testx.vbs")); 

  %end;
  %else %put %str(ERR)OR: [&SYSMACRONAME.] Unable to open: &WorkBookPath.  - check it exists!;


%mend;

Dengan DDE Anda dapat mengatur filter di SAS:

data _null_;
    FILE CMDS;
    /* select your worksheet */
    put '[workbook.select("your_sheet")]';
    /* select the column range you want to set the filter */
    put '[select("r1c2:r1c5")]';
    /* set filter */
    put '[filter]';
run;