Decoder Kode Morse di Perl

Kode Anda mengandung dua kesalahan sintaksis: foreach memerlukan daftar untuk mengulanginya; ini artinya orang tua. Tidak seperti C dan bahasa lainnya, Perl tidak mendukung else if (...). Sebagai gantinya, gunakan elsif (...).

Lalu ada beberapa kesalahan semantik: Nilai iterasi saat ini disimpan di $_. Array @_ berisi argumen panggilan ke fungsi Anda.

Perl membandingkan string dan angka secara berbeda:

Strings Numbers
eq      ==
lt      <
gt      >
le      <=
ge      >=
ne      !=
cmp     <=>

Gunakan operator yang benar untuk tugas yang ada, dalam hal ini, operator berserabut.

(Kode Anda @_ == @k melakukan sesuatu, yaitu menggunakan array dalam konteks numerik. Ini menghasilkan jumlah elemen, yang kemudian dibandingkan. @_ == '!' sungguh aneh.)

Yang sebenarnya ingin Anda lakukan adalah memetakan nilai yang dimasukkan ke daftar karakter. Hash Anda mendefinisikan pemetaan ini, tetapi kami ingin menerapkannya. Perl memiliki fungsi map, cara kerjanya seperti itu

@out_list = map { ACTION } @in_list;

Di dalam blok tindakan, nilai saat ini tersedia sebagai $_.

Kita ingin tindakan kita mencari nilai yang sesuai dalam hash, atau menyertakan pesan kesalahan jika tidak ada pemetaan untuk string input:

my @letters = map { $morsecode{$_} // "<unknown code $_>" } @message;

Ini mengasumsikan ! terdaftar sebagai spasi di hash kode morse.

Kami kemudian membuat satu string dari huruf-huruf ini dengan joining dengan string kosong:

my $translated_message = join "", @letters;

Dan jangan lupa untuk mencetak hasilnya!

Kode lengkapnya:

#!/usr/bin/perl
use strict; use warnings; use 5.012;

my %morsecode=(
  '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
  '.'     =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
  '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
  '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
  '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-'     =>'T',
  '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
  '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
  '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
  '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
  '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
  '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'"',
  '!'     =>' ',
);

say "Please type in your morse message:";
my @codes = <>;
chomp @codes;

my $message = join "", map { $morsecode{$_} // "<unknown code $_>" } @codes;

say "You said:";
say $message;

Ini menghasilkan keluaran yang diinginkan.

Ada banyak manfaat dalam mempelajari bagaimana dan mengapa, tapi inilah alasannya:

sub encode {
  my $output;
  foreach my $symbol (@_) {
    my $letter = $morsecode{$symbol};
    die "Don't know how to decode $symbol" unless defined $letter;
    $output .= $letter
  }
  return $output;
}

atau bahkan hanya sub encode { join '', map $morsecode{$_}, @_ } jika Anda tidak terlalu khawatir dengan pemeriksaan kesalahan. @k dan @v tidak diperlukan untuk apa pun.

Mencari nilai dalam hash adalah pekerjaan yang sangat intens, sebaiknya Anda hanya menggunakan hash terbalik. Anda dapat dengan mudah membalikkan hash dengan fungsi terbalik di Perl. Selain itu, saat melihat kode Anda, saya telah melihat bahwa Anda dapat memasukkan input huruf kecil. Namun saat mencari hash pada kunci, ini peka huruf besar-kecil. Jadi, Anda perlu huruf besar masukan Anda. Selain itu, saya tidak terlalu menyukai cara "mengakhiri" STDIN. Kata/tanda keluar akan lebih baik dan lebih bersih.

Saya mengambil kode Anda

my %morsecode=(
    '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
    '.' =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
    '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
    '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
    '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-' =>'T',
    '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
    '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
    '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
    '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
    '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
    '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'\"'
);
my %reversemorse = reverse %morsecode;
print "Enter a message\n";
chomp (my $message = <STDIN>);
print &encode($message);

sub encode{
    my $origmsg = shift(@_);
    my @letters = split('',$origmsg);
    my $morse = '';
    foreach $l(@letters)
    {
        $morse .= $reversemorse{uc($l)}." ";
    }    
    return $morse;
}