Команда Windows для преобразования окончаний строк Unix?

На самом деле это можно сделать очень легко с помощью команды more, которая включена в Windows NT и более поздние версии. Чтобы преобразовать input_filename, содержащий UNIX EOL (конец строки) \n, в output_filename, содержащий Windows EOL \r\n, просто сделайте следующее:

TYPE input_filename | MORE /P > output_filename

У команды more есть дополнительные параметры форматирования, о которых вы, возможно, не знали. Запустите more/?, чтобы узнать, что еще more умеет.

Воспользуйтесь утилитой unix2dos. Вы можете загрузить двоичные файлы здесь.

Я имел дело с CRLF проблемами, поэтому решил создать действительно простой инструмент для преобразования (на NodeJS):

Это интерфейс командной строки конвертера EOL для NodeJS

Итак, если у вас установлен NodeJS с npm, вы можете попробовать:

npm i -g eol-converter-cli
eolConverter crlf "**/*.{txt,js,java,etc}"

Путь можно настроить динамически с помощью регулярного выражения Glob (такое же регулярное выражение, как в оболочке).

Так что, если вы можете использовать NodeJS, это действительно просто, и вы можете интегрировать эту команду для преобразования всего рабочего пространства в желаемые окончания строк.

Вы можете сделать это без дополнительных инструментов в VBScript:

Do Until WScript.StdIn.AtEndOfStream
  WScript.StdOut.WriteLine WScript.StdIn.ReadLine
Loop

Поместите указанные выше строки в файл unix2dos.vbs и запустите его следующим образом:

cscript //NoLogo unix2dos.vbs <C:\path\to\input.txt >C:\path\to\output.txt

или вот так:

type C:\path\to\input.txt | cscript //NoLogo unix2dos.vbs >C:\path\to\output.txt

Вы также можете сделать это в PowerShell:

(Get-Content "C:\path\to\input.txt") -replace "`n", "`r`n" |
  Set-Content "C:\path\to\output.txt"

который можно еще упростить до следующего:

(Get-Content "C:\path\to\input.txt") | Set-Content "C:\path\to\output.txt"

Вышеупомянутый оператор работает без явной замены, потому что Get-Content неявно разделяет входные файлы при любом типе разрыва строки (CR, LF и CR-LF), а Set-Content присоединяет входной массив с разрывами строк Windows (CR-LF) перед записью его в файл.

Windows MORE ненадежен, он неизбежно уничтожает табуляторы и добавляет строки.

unix2dos также является частью MinGW / MSYS, Cygutils, GnuWin32 и других коллекций двоичных портов unix - и, возможно, уже быть установлен.

Когда есть python, этот однострочный преобразователь преобразует любые окончания строк в текущую платформу - на любая платформа:

TYPE UNIXFILE.EXT | python -c "import sys; sys.stdout.write(sys.stdin.read())" > MYPLATFILE.EXT

or

python -c "import sys; sys.stdout.write(open(sys.argv[1]).read())" UNIXFILE.EXT > MYPLATFILE.EXT

Или поместите однострочник в сценарий .bat / shell и в PATH в соответствии с вашей платформой:

@REM This is any2here.bat
python -c "import sys; sys.stdout.write(open(sys.argv[1]).read())" %1

и используйте этот инструмент, например

any2here UNIXFILE.EXT > MYPLATFILE.EXT

Основываясь на полезных ответах TampaHaze и MD XF.

Это изменит все файлы .txt на месте в текущем каталоге с LF на CRLF в командной строке.

for /f %f in ('dir /b "*.txt"') do ( type %f | more /p > %f.1 & move %f.1 %f )

Если вы не хотите проверять каждое изменение

переехать

To

движение / г

Чтобы включить изменение подкаталогов

dir / b

To

dir / b / s

Чтобы сделать все это в пакетном файле, включая подкаталоги, без запроса использования ниже

@echo off
setlocal enabledelayedexpansion

for /f %%f in ('dir /s /b "*.txt"') do (
    type %%f | more /p > %%f.1 
    move /y %%f.1 %%f > nul
    @echo Changing LF-^>CRLF in File %%f
)
echo.
pause

попробуй это:

(for /f "delims=" %i in (file.unix) do @echo %i)>file.dos

Протокол сеанса:

C:\TEST>xxd -g1 file.unix
0000000: 36 31 36 38 39 36 32 39 33 30 38 31 30 38 36 35  6168962930810865
0000010: 0a 34 38 36 38 39 37 34 36 33 32 36 31 38 31 39  .486897463261819
0000020: 37 0a 37 32 30 30 31 33 37 33 39 31 39 32 38 35  7.72001373919285
0000030: 34 37 0a 35 30 32 32 38 31 35 37 33 32 30 32 30  47.5022815732020
0000040: 35 32 34 0a                                      524.

C:\TEST>(for /f "delims=" %i in (file.unix) do @echo %i)>file.dos

C:\TEST>xxd -g1 file.dos
0000000: 36 31 36 38 39 36 32 39 33 30 38 31 30 38 36 35  6168962930810865
0000010: 0d 0a 34 38 36 38 39 37 34 36 33 32 36 31 38 31  ..48689746326181
0000020: 39 37 0d 0a 37 32 30 30 31 33 37 33 39 31 39 32  97..720013739192
0000030: 38 35 34 37 0d 0a 35 30 32 32 38 31 35 37 33 32  8547..5022815732
0000040: 30 32 30 35 32 34 0d 0a                          020524..

Мой вклад в это, преобразование нескольких файлов в папку: for %%z in (*.txt) do (for /f "delims=" %%i in (%%z) do @echo %%i)>%%z.tmp

Вы можете создать простой пакетный скрипт, который сделает это за вас:

TYPE %1 | MORE /P >%1.1
MOVE %1.1 %1

Затем запустите <batch script name> <FILE>, и <FILE> будет немедленно преобразован в окончания строки DOS.

Я клонировал свой проект git, используя git bash на windows. Все файлы тогда имели LF окончания. В нашем репозитории по умолчанию CRLF окончания.

Я удалил проект, а затем снова клонировал его с помощью Windows Command Prompt. Концовки CRLF тогда остались нетронутыми. В моем случае, если бы я изменил концовку проекта, это привело бы к огромной фиксации и доставило бы проблемы моим товарищам по команде. Итак, сделал это так. Надеюсь, это кому-то поможет.

Если у вас есть bash (например, git bash), вы можете использовать следующий скрипт для преобразования из unix2dos:

ex filename.ext <<EOF
:set fileformat=dos
:wq
EOF

аналогично, чтобы преобразовать из dos2unix:

ex filename.ext <<EOF
:set fileformat=unix
:wq
EOF

Вот простой файл unix2dos.bat, который сохраняет пустые строки и восклицательные знаки:

@echo off
setlocal DisableDelayedExpansion
for /f "tokens=1,* delims=:" %%k in ('findstr /n "^" %1') do echo.%%l

Вывод будет стандартным, поэтому при желании перенаправьте вывод unix2dos.bat в файл.

Он позволяет избежать ошибок других ранее предложенных решений для / f пакетного цикла:
1) Работает с отключением отложенного раскрытия, чтобы избежать съедания восклицательных знаков.
2) Использование самого токенизатора for / f для удаления строки число из findstr /n строк вывода.
(Использование findstr / n необходимо также для получения пустых строк: они будут отброшены, если для / f читать непосредственно из входного файла.)

Но, как отметил Джеб в комментарии ниже, вышеуказанное решение имеет один недостаток, которого нет у других: оно отбрасывает двоеточия в начале строк.

Итак, обновление 2020-04-06 просто для удовольствия, вот еще один однострочный файл на основе findstr.exe, который, похоже, отлично работает без указанных выше недостатков:

@echo off
setlocal DisableDelayedExpansion
for /f "tokens=* delims=0123456789" %%l in ('findstr /n "^" %1') do echo%%l

Дополнительные приемы:
3) Используйте цифры 0–9 в качестве разделителей, чтобы tokens=* пропускал начальный номер строки.
4) Используйте двоеточие, вставленное через findstr /n после номера строки, в качестве разделителя токенов после эхо-команда.

Я оставлю это Джебу, чтобы он объяснил, есть ли крайние случаи, когда echo:something может выйти из строя :-)
Все, что я могу сказать, это то, что эта последняя версия успешно восстановила окончания строк на моем огромном batch library, поэтому исключения, если таковые имеются, должны быть довольно редкими!

Основываясь на ответе Эндоро, но чтобы сохранить пробелы, попробуйте следующее:

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=* delims=:" %%i in ('findstr /n "^" file.unix') do (
        set line=%%i
        set line=!line:*:=!
        echo(!line!
        ))>file.dos

Поздно, но все еще нет правильного ответа с использованием цикла FOR /F.
(Но вам вообще не нужен цикл FOR, решение от @TampaHaze тоже работает и намного проще)

У ответа от @IR related есть некоторые недостатки.
Он удаляет восклицательные знаки, а также может отбрасывать символы вставки.

@echo off
(
    setlocal Disabledelayedexpansion
    for /f "tokens=* delims=" %%L in ('findstr /n "^" "%~1"') do (
        set "line=%%L"
        setlocal enabledelayedexpansion
        set "line=!line:*:=!"
        (echo(!line!)
        endlocal
    )
) > file.dos

Уловка состоит в том, чтобы использовать findstr /n для префикса каждой строки с <line number>:, это позволяет избежать пропуска пустых строк или строк, начинающихся с ;.
Чтобы удалить <number>: параметр FOR "tokens=1,* delims=:" нельзя использовать, потому что это приведет к удалению всех начальных двоеточий в линия тоже.

Поэтому номер строки удаляется с помощью set "line=!line:*:=!", для этого требуется EnableDelayedExpansion.
Но с EnableDelayedExpansion в строке set "line=%%L" будут удалены все восклицательные знаки, а также символы вставки (только если в строке есть восклицательные знаки).

Вот почему я отключил отложенное расширение раньше и включил его только для двух строк, где это необходимо.

(echo(!line!) выглядит странно, но имеет то преимущество, что echo( может отображать любой контент в !line!, а внешняя скобка позволяет избежать случайных пробелов в конце строки.

Для преобразования UNIX (LF) в Windows (CR-LF) используйте следующую команду на вашем терминале Windows.

type file.txt > new_file.txt

Я прохожу курс AWS, и мне часто приходилось копировать текстовые поля в веб-формах AWS в Блокнот Windows. Таким образом, я получаю текст с разделителями LF только в моем буфере обмена. Я случайно обнаружил, что вставив его в мой редактор Delphi, а затем нажав Ctrl + K + W, я запишу текст в файл с разделителями CR + LF. (Готов поспорить, что многие другие редакторы IDE поступили бы так же).

Вставка возвратов каретки в Текстовый файл

@echo off
set SourceFile=%1 rem c:\test\test.txt
set TargetFile=%2 rem c:\test\out.txt

if exist "%TargetFile%" del "%TargetFile%"
for /F "delims=" %%a in ('type "%SourceFile%"') do call :Sub %%a
rem notepad "%TargetFile%"
goto :eof


:Sub
echo %1 >> "%TargetFile%"
if "%2"=="" goto :eof
shift
goto sub