Как я могу удалить внешние ссылки из HTML с помощью Perl?

Повторяя комментарий Криса Лутца, я надеюсь, что следующее показывает, что действительно просто использовать синтаксический анализатор (особенно если вы хотите иметь возможность иметь дело с вводом, который вы еще не видели, например <a class="external" href="...">), вместо того, чтобы собирать хрупкие решения с использованием s///.

Если вы собираетесь пойти по пути s///, по крайней мере, будьте честны, полагайтесь на href атрибуты, написанные полностью в верхнем регистре, а не создавайте иллюзию гибкости.

Изменить: По многочисленным просьбам ;-), вот версия с использованием HTML :: TokeParser :: Simple. Просматривайте историю изменений для версии, используя только HTML :: TokeParser.

#!/usr/bin/perl

use strict; use warnings;
use HTML::TokeParser::Simple;

my $parser = HTML::TokeParser::Simple->new(\*DATA);

while ( my $token = $parser->get_token ) {
    if ($token->is_start_tag('a')) {
        my $href = $token->get_attr('href');
        if (defined $href and $href !~ /^#/) {
            print $parser->get_trimmed_text('/a');
            $parser->get_token; # discard </a>
            next;
        }
    }
    print $token->as_is;
}

__DATA__
<a HREF="#FN1" name="01">1</a>
some other html
<a href="155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="test.html">click here >>></a>
either</p>

Вывод:

C:\Temp> hjk
<a HREF="#FN1" name="01">1</a>
some other html
No. 155 <!-- end tag not necessarily on the same line -->
An example you might not have considered

<p>Maybe you did not consider click here >>>
either</p>

NB: решение на основе регулярных выражений, которое вы отметили как "правильное", не работает, если файлы, которые связаны, имеют расширение .html, а не .htm. Учитывая это, я считаю, что ваша забота о том, чтобы не полагаться на верхний регистр HREF атрибутов, неоправданна. Если вы действительно хотите быстро и грязно, вам не следует беспокоиться ни о чем другом, а следует полагаться на все заглавные буквы HREF и покончить с этим. Однако, если вы хотите, чтобы ваш код работал с гораздо большим количеством документов и дольше, вам следует использовать соответствующий синтаксический анализатор.

Парсер типа SAX немного больше похож на HTML::Parser:

use strict;
use warnings;

use English qw<$OS_ERROR>;
use HTML::Parser;
use List::Util qw<first>;

my $omitted;

sub tag_handler { 
    my ( $self, $tag_name, $text, $attr_hashref ) = @_;
    if ( $tag_name eq 'a' ) { 
        my $href = first {; defined } @$attr_hashref{ qw<href HREF> };
        $omitted = substr( $href, 0, 7 ) eq 'http://';
        return if $omitted;
    }
    print $text;
}

sub end_handler { 
    my $tag_name = shift;
    if ( $tag_name eq 'a' && $omitted ) { 
        $omitted = false;
        return;
    }
    print shift;
}

my $parser
    = HTML::Parser->new( api_version => 3
                       , default_h   => [ sub { print shift; }, 'text' ]
                       , start_h     => [ \&tag_handler, 'self,tagname,text,attr' ]
                       , end_h       => [ \&end_handler, 'tagname,text' ]
                       );
$parser->parse_file( $path_to_file ) or die $OS_ERROR;

Еще одно решение. Мне нравится HTML :: TreeBuilder и семья.

#!/usr/bin/perl
use strict;
use warnings;
use HTML::TreeBuilder;

my $root = HTML::TreeBuilder->new_from_file(\*DATA);
foreach my $a ($root->find_by_tag_name('a')) {
    if ($a->attr('href') !~ /^#/) {
        $a->replace_with_content($a->as_text);
    }
}
print $root->as_HTML(undef, "\t");

__DATA__
<a HREF="#FN1" name="01">1</a>
some other html
<a href="155.htm">No. 155
</a> <!-- end tag not necessarily on the same line -->
<a class="external" href="http://example.com">An example you
might not have considered</a>

<p>Maybe you did not consider <a
href="test.html">click here >>></a>
either</p>

Почему бы просто не удалить только те ссылки, для которых атрибут href не начинается со знака решетки? Что-то вроде этого:

html =~ s/<a href="[^#][^"]*?">(.+?)<\/a>/$1/sig;

Еще проще, если вам не нужны атрибуты тегов:

$html =~ s/<a[^>]+>(.+?)<\/a>/$1/sig;