Декодер азбуки Морзе на Perl

Ваш код содержит две синтаксические ошибки: foreach требуется список для повторения; это означает паренс. В отличие от C и других языков, Perl не поддерживает else if (...). Вместо этого используйте elsif (...).

Затем есть несколько семантических ошибок: Текущее значение итерации хранится в $_. Массив @_ содержит аргументы вызова вашей функции.

Perl сравнивает строки и числа по-разному:

Strings Numbers
eq      ==
lt      <
gt      >
le      <=
ge      >=
ne      !=
cmp     <=>

Используйте правильные операторы для поставленной задачи, в данном случае — строгие.

(Ваш код @_ == @k что-то делает, а именно использует массивы в числовом контексте. Это дает количество элементов, которые впоследствии сравниваются. @_ == '!' просто странно.)

Что вы действительно хотите сделать, так это сопоставить введенные значения со списком символов. Ваш хэш определяет это сопоставление, но мы хотим его применить. В Perl есть функция map, она работает как

@out_list = map { ACTION } @in_list;

Внутри блока действий текущее значение доступно как $_.

Мы хотим, чтобы наше действие искало соответствующее значение в хеше или включало сообщение об ошибке, если для входной строки нет сопоставления:

my @letters = map { $morsecode{$_} // "<unknown code $_>" } @message;

Это предполагает, что ! зарегистрировано как пробел в хэше кода Морзе.

Затем мы создаем единую строку из этих букв, joinсоединяя их с пустой строкой:

my $translated_message = join "", @letters;

И не забудьте распечатать результат!

Полный код:

#!/usr/bin/perl
use strict; use warnings; use 5.012;

my %morsecode=(
  '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
  '.'     =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
  '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
  '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
  '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-'     =>'T',
  '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
  '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
  '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
  '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
  '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
  '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'"',
  '!'     =>' ',
);

say "Please type in your morse message:";
my @codes = <>;
chomp @codes;

my $message = join "", map { $morsecode{$_} // "<unknown code $_>" } @codes;

say "You said:";
say $message;

Это дает желаемый результат.

Очень важно узнать, как и почему, но вот что:

sub encode {
  my $output;
  foreach my $symbol (@_) {
    my $letter = $morsecode{$symbol};
    die "Don't know how to decode $symbol" unless defined $letter;
    $output .= $letter
  }
  return $output;
}

или даже всего sub encode { join '', map $morsecode{$_}, @_ }, если вы не слишком беспокоитесь о проверке ошибок. @k и @v ни для чего не нужны.

Поиск значений в хэшах — очень интенсивная работа, вам лучше просто использовать обратный хеш. Вы можете легко обратить хэш с помощью обратной функции в Perl. Кроме того, наблюдая за вашим кодом, я увидел, что вы сможете вводить строчные буквы. Но при поиске в хэшах по ключам учитывается регистр. Таким образом, вам нужно заглавные вводимые данные. Кроме того, мне не очень нравится способ «завершить» STDIN. Выходное слово/знак было бы лучше и чище.

Мое мнение о вашем коде

my %morsecode=(
    '.-'    =>'A',  '-...'  =>'B',  '-.-.'  =>'C',  '-..'   =>'D',
    '.' =>'E',  '..-.'  =>'F',  '--.'   =>'G',  '....'  =>'H',
    '..'    =>'I',  '.---'  =>'J',  '-.-'   =>'K',  '.-..'  =>'L',
    '--'    =>'M',  '-.'    =>'N',  '---'   =>'O',  '.--.'  =>'P',
    '--.-'  =>'Q',  '.-.'   =>'R',  '...'   =>'S',  '-' =>'T',
    '..-'   =>'U',  '...-'  =>'V',  '.--'   =>'W',  '-..-'  =>'X',
    '-.--'  =>'Y',  '--..'  =>'Z',  '.----' =>'1',  '..---' =>'2',
    '...--' =>'3',  '....-' =>'4',  '.....' =>'5',  '-....' =>'6',
    '--...' =>'7',  '---..' =>'8',  '----.' =>'9',  '-----' =>'0',
    '.-.-.-'=>'.',  '--..--'=>',',  '---...'=>':',  '..--..'=>'?',
    '.----.'=>'\'', '-...-' =>'-',  '-..-.' =>'/',  '.-..-.'=>'\"'
);
my %reversemorse = reverse %morsecode;
print "Enter a message\n";
chomp (my $message = <STDIN>);
print &encode($message);

sub encode{
    my $origmsg = shift(@_);
    my @letters = split('',$origmsg);
    my $morse = '';
    foreach $l(@letters)
    {
        $morse .= $reversemorse{uc($l)}." ";
    }    
    return $morse;
}