XSLT: извлечение уникальных значений атрибутов

Пожалуйста, помогите, я новичок в XSLT и пытаюсь преобразовать один формат XML в другой.

Мне нужно извлечь уникальные значения атрибутов и преобразовать их в новый формат. В приведенном ниже примере XML показаны исходный и новый / целевой форматы.

Я потратил целую вечность, пытаясь сделать это без всякого удовольствия. Может ли кто-нибудь помочь или подсказать?

Исходный формат:

<base>
  <level>
    <level2 Name ="AA" value="1"/>
  </level>
  <level>
    <level2 Name ="BB" value="2"/>
  </level>
  <level>
    <level2 Name ="BB" value="3"/>
  </level>
  <level>
    <level2 Name ="CC" value="4"/>
  </level>
  <level>
    <level2 Name ="AA" value="5"/>
  </level>
</base>

Новый формат:

<base>
  <levelNames>
    <level level2Name ="AA"/>
    <level level2Name ="BB"/>
    <level level2Name ="CC"/>
  </levelNames>
</base>

Большое спасибо.


xslt grouping
person SuperSuperDev1234    schedule 02.07.2009    source источник
comment
Опубликуйте, какой XSLT вы уже пробовали, и мы внесем предложения   -  person skaffman    schedule 02.07.2009

Ответы (3)


arrow_upward
11
arrow_downward

XSLT Soln:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:key name="LevelDistint" match="level2" use="@Name"/>
    <xsl:template match="base">
        <base>
            <levelNames>
                <xsl:for-each select="level/level2[generate-id() = generate-id(key('LevelDistint', @Name)[1])]">
                    <level>
                        <xsl:attribute name="level2Name"><xsl:value-of select="normalize-space(@Name)"/></xsl:attribute>
                    </level>
                </xsl:for-each>
            </levelNames>
        </base>
    </xsl:template>
</xsl:stylesheet>

XSLT O / P:

<?xml version="1.0" encoding="UTF-8"?>
<base>
    <levelNames>
        <level level2Name="AA"/>
        <level level2Name="BB"/>
        <level level2Name="CC"/>
    </levelNames>
</base>
person SO User    schedule 03.07.2009

arrow_upward
2
arrow_downward

И снова техника группировки Мюнчи, похоже, является недостающей частью.

Это довольно банальная проблема, поэтому я позволю вам сделать свою работу, чтобы разобраться с Мюнхом.

person annakata    schedule 02.07.2009
comment
У меня двоякое мнение между голосованием и продвижением вперед, публикацией решения и чувством вины за него. Будь ты проклят. :-D Но вы, наверное, правы, подозревая, что это домашнее задание, поэтому воздерживаюсь. - person Tomalak; 02.07.2009
comment
Если вы сделали это однажды, вы увидите, насколько это на самом деле легко. Вам просто нужно понять идею. Для наиболее распространенных проблем XSLT я действительно рекомендую сначала посмотреть здесь: dpawson.co .uk / xsl / sect2 / sect21.html. - person Boldewyn; 02.07.2009
comment
@Boldewyn - да, это отличный ресурс для новичков, хоть и некрасивый :) - person annakata; 02.07.2009
comment
вздох кто-нибудь может объяснить отрицательный голос? Это потому, что я не выполнял за него работу ОП? - person annakata; 03.07.2009

arrow_upward
0
arrow_downward

Пожалуйста, создайте первый xsl: key, тогда вы можете легко использовать приведенный ниже код.

xsl: key name = "levelName" match = "level2" use = "@ Name"

<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="base">
    <xsl:element name="{local-name(.)}">
        <xsl:element name="levelNames">
           <xsl:apply-templates/>
        </xsl:element>
    </xsl:element>
</xsl:template>

    <xsl:template match="level">
        <xsl:for-each select="level2[count(.|key('levelName', @Name)[1]) = 1]">
            <xsl:sort order="ascending" data-type="text" select="@Name"/>
            <xsl:element name="{local-name(..)}">
                <xsl:attribute name="level2Name">
                    <xsl:value-of select="@Name"/>
                </xsl:attribute>
            </xsl:element>
        </xsl:for-each>
    </xsl:template>
person Community    schedule 02.07.2009